!***********************************************************************
! This file is part of OpenMolcas.                                     *
!                                                                      *
! OpenMolcas is free software; you can redistribute it and/or modify   *
! it under the terms of the GNU Lesser General Public License, v. 2.1. *
! OpenMolcas is distributed in the hope that it will be useful, but it *
! is provided "as is" and without any express or implied warranties.   *
! For more details see the full text of the license in the file        *
! LICENSE or in <http://www.gnu.org/licenses/>.                        *
!***********************************************************************

subroutine grc32C(a,b,c,mvec,ssa,ssb,pbar,ix)

use ccsd_global, only: dimm, Map_Type, mmul, nsym
use Definitions, only: iwp

implicit none
type(Map_Type), intent(in) :: a, b
type(Map_Type), intent(inout) :: c
integer(kind=iwp), intent(out) :: mvec(4096,7)
integer(kind=iwp), intent(in) :: ssa, ssb, pbar
integer(kind=iwp), intent(inout) :: ix
integer(kind=iwp) :: ia, ib, ic, nhelp1, nhelp2, nhelp21, nhelp22, nhelp3, nhelp4, nsyma2, ntest1, posct, sa1, sa12, sa2, sa3, &
                     sb1, sb2

!1*

if (pbar == 1) then

  ! structure A(p,qr)*B(qr)=y(p)
  ! implemented in grc32y

else if (pbar == 2) then

  ! structure A(pq,r)*B(r,s)=C(pq,s)

  !1.0 prepare c%d,c%i

  call grc0(3,b%d(0,6),a%d(0,1),a%d(0,2),b%d(0,2),0,mmul(ssa,ssb),posct,c)

  !1.1 define limitations - p>q,r must be tested - ntest1

  if (b%d(0,6) == 1) then
    ntest1 = 1
  else
    ntest1 = 0
  end if

  !1.2 def symm states and test the limitations

  ix = 1
  do sa1=1,nsym
    if (ntest1 == 1) then
      nsyma2 = sa1
    else
      nsyma2 = nsym
    end if

    do sa2=1,nsyma2
      sa12 = mmul(sa1,sa2)

      sa3 = mmul(ssa,sa12)
      sb1 = sa3

      sb2 = mmul(ssb,sb1)

      !1.3 def mvec,c%d and c%i

      ia = a%i(sa1,sa2,1)
      ib = b%i(sb1,1,1)
      ic = c%i(sa1,sa2,1)

      ! yes/no
      if ((a%d(ia,2) <= 0) .or. (b%d(ib,2) <= 0)) cycle
      nhelp1 = 1

      ! rowA
      nhelp21 = dimm(a%d(0,1),sa1)
      nhelp22 = dimm(a%d(0,2),sa2)
      if ((ntest1 == 1) .and. (sa1 == sa2)) then
        nhelp2 = nhelp21*(nhelp21-1)/2
      else
        nhelp2 = nhelp21*nhelp22
      end if

      ! colB
      nhelp3 = dimm(b%d(0,2),sb2)

      ! sum
      nhelp4 = dimm(a%d(0,3),sa3)

      mvec(ix,1) = nhelp1
      mvec(ix,2) = a%d(ia,1)
      mvec(ix,3) = b%d(ib,1)
      mvec(ix,4) = c%d(ic,1)
      mvec(ix,5) = nhelp2
      mvec(ix,6) = nhelp4
      mvec(ix,7) = nhelp3

      ix = ix+1

    end do
  end do

end if
ix = ix-1

return

end subroutine grc32C
